home *** CD-ROM | disk | FTP | other *** search
/ Power Programmierung / Power-Programmierung (Tewi)(1994).iso / magazine / nan_news / toolkit / restatt.asm < prev    next >
Assembly Source File  |  1991-08-15  |  7KB  |  165 lines
  1. ; File......: RESTATT.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   15 Aug 1991 23:08:02  $
  4. ; Revision..: $Revision:   1.1  $
  5. ; Log file..: $Logfile:   E:/nanfor/src/restatt.asv  $
  6. ; 
  7. ; This is an original work by Ted Means and is placed in the
  8. ; public domain.
  9. ;
  10. ; Modification history:
  11. ; ---------------------
  12. ;
  13. ; $Log:   E:/nanfor/src/restatt.asv  $
  14. ;  
  15. ;     Rev 1.1   15 Aug 1991 23:08:02   GLENN
  16. ;  Forest Belt proofread/edited/cleaned up doc
  17. ;  
  18. ;     Rev 1.0   12 Jun 1991 01:30:14   GLENN
  19. ;  Initial revision.
  20. ;
  21.  
  22.  
  23. ;  $DOC$
  24. ;  $FUNCNAME$
  25. ;     FT_RESTATT()
  26. ;  $CATEGORY$
  27. ;     Video
  28. ;  $ONELINER$
  29. ;     Restore the attribute bytes of a specified screen region.
  30. ;  $SYNTAX$
  31. ;     FT_RESTATT( <nTop>, <nLeft>, <nBottom>, <nRight>, <cAttributes> ) -> NIL
  32. ;  $ARGUMENTS$
  33. ;     <nTop>, <nLeft>, <nBottom>, and <nRight> define the screen region.
  34. ;     <cAttributes> is a character string containing the attribute bytes
  35. ;                   for the screen region.  This will most often be a string
  36. ;                   previously returned by FT_SAVEATT(), but any character
  37. ;                   string may be used (provided it is of the proper size).
  38. ;  $RETURNS$
  39. ;     NIL
  40. ;  $DESCRIPTION$
  41. ;     This function is similar to Clipper's RestScreen(), except that it only
  42. ;     restores the attribute bytes.  This is useful if you want to change the
  43. ;     screen color without affecting the text.
  44. ;
  45. ;     *** INTERNALS ALERT ***
  46. ;
  47. ;     This function calls the Clipper internal __gtMaxCol to obtain the
  48. ;     maximum column value for the current video mode.  If you're too gutless
  49. ;     to use internals, then this function isn't for you.
  50. ;  $EXAMPLES$
  51. ;     // Restore attributes of row 4
  52. ;     FT_RESTATT( 4, 0, 4, maxcol(), cBuffer)
  53. ;
  54. ;     // Restore attributes to middle of screen
  55. ;     FT_RESTATT(10,20,14,59,cBuffer)
  56. ;  $SEEALSO$
  57. ;     FT_SAVEATT()
  58. ;  $END$
  59. ;
  60.  
  61.         IDEAL
  62.  
  63. Public   FT_RESTATT
  64.  
  65. Extrn    __ParNI:Far
  66. Extrn    __ParC:Far
  67. Extrn    __gtMaxCol:Far                      ; INTERNAL!!  INTERNAL!!
  68.  
  69. Upper    EQU       Word Ptr BP - 2
  70. Left     EQU       Word Ptr BP - 4
  71. Lower    EQU       Word Ptr BP - 6
  72. Right    EQU       Word Ptr BP - 8
  73. MaxCol   EQU       Word Ptr BP - 10
  74.  
  75. Segment  _NanFor   Word      "CODE"
  76.          Assume    CS:_NanFor
  77.  
  78. Proc     FT_RESTATT          Far
  79.  
  80.          Push      BP                        ; Save BP
  81.          Mov       BP,SP                     ; Set up stack reference
  82.          Sub       SP,10                     ; Allocate space for locals
  83.  
  84.          Call      __gtMaxCol                ; Get current value of maxcol()
  85.          Inc       AX                        ; Get column count
  86.          Mov       [MaxCol],AX               ; Store in local
  87.  
  88.          Mov       AX,1                      ; Specify param #1
  89.          Push      AX                        ; Put on stack
  90.          Call      __ParNI                   ; Get value
  91.          Mov       [Upper],AX                ; Store in local
  92.  
  93.          Mov       AX,2                      ; Specify param #2
  94.          Push      AX                        ; Put on stack
  95.          Call      __ParNI                   ; Get value
  96.          Mov       [Left],AX                 ; Store in local
  97.  
  98.          Mov       AX,3                      ; Specify param #3
  99.          Push      AX                        ; Put on stack
  100.          Call      __ParNI                   ; Get value
  101.          Mov       [Lower],AX                ; Store in local
  102.  
  103.          Mov       AX,4                      ; Specify param #4
  104.          Push      AX                        ; Put on stack
  105.          Call      __ParNI                   ; Get value
  106.          Mov       [Right],AX                ; Store in local
  107.  
  108.          Mov       AX,5                      ; Specify param #5
  109.          Push      AX                        ; Put on stack
  110.          Call      __ParC                    ; Get pointer to buffer
  111.          Add       SP,10                     ; Realign stack
  112.  
  113. SetPtr:  Push      DS                        ; Save registers and ensure
  114.          Push      SI                        ; clear direction flag
  115.          Push      DI
  116.          CLD
  117.  
  118.          Mov       DS,DX                     ; Set up DS:SI to point to
  119.          Mov       SI,AX                     ; passed buffer
  120.          Xor       AX,AX                     ; Clear AX
  121.          Mov       ES,AX                     ; Point ES to low memory
  122.          Mov       AX,0B800h                 ; Initalize video base
  123.          Cmp       [Word Ptr ES:463h],3B4h   ; Monochrome?
  124.          JNE       SetVid                    ; No, continue
  125.          Mov       AX,0B000h                 ; Set video base to mono
  126.  
  127. SetVid:  Mov       ES,AX                     ; Set video base
  128.          Xor       DI,DI                     ; Start at offset 0
  129.          Mov       CX,[Lower]                ; Get lower row
  130.          Sub       CX,[Upper]                ; Subtract upper row
  131.          Inc       CX                        ; Get number of rows
  132.  
  133. Rows:    Mov       AX,CX                     ; Get row number
  134.          Sub       AX,[Lower]                ; Subtract last row
  135.          Dec       AX                        ; Get negation of row
  136.          Neg       AX                        ; Convert to abs()
  137.          Mul       [MaxCol]                  ; Multiply by column count
  138.          SHL       AX,1                      ; Multiply by two
  139.          Mov       BX,[Left]                 ; Get left column
  140.          SHL       BX,1                      ; Multiply by two
  141.          Inc       BX                        ; Point to attribute byte
  142.          Add       BX,AX                     ; Add rows * columns
  143.          Push      CX                        ; Save row indicator
  144.          Mov       CX,[Right]                ; Load right column
  145.          Sub       CX,[Left]                 ; Subtract left column
  146.          Inc       CX                        ; Get number of columns
  147. Cols:    Lodsb                               ; Get attribute byte
  148.          Mov       [Byte Ptr ES:BX + DI],AL  ; Store attribute byte
  149.          Add       BX,2                      ; Point to next attribute byte
  150.          Loop      Cols                      ; Get next byte
  151.          Pop       CX                        ; Restore row indicator
  152.          Loop      Rows                      ; Do next row
  153.  
  154. Done:    Pop       DI
  155.          Pop       SI
  156.          Pop       DS
  157.          Mov       SP,BP
  158.          Pop       BP
  159.          Ret
  160. Endp     FT_RESTATT
  161. Ends     _NanFor
  162. End
  163.  
  164.  
  165.